const int buttons[] = {1, 2, 3, 4}; // Pinnen voor de knoppen

const int leds[] = {5, 6, 7, 8}; // Pinnen voor de leds

const int speaker = 9; // Pin voor de luidspreker

const int notes[] = {523, 659, 784, 1047}; // Melodienoten: C5, E5, G5, C6

bool guessing = false; // Spelstatus: true = speler raadt, false = melodie wordt voorgespeeld

int lastButton = -1; // Laatst ingedrukte knop: 0 - 3 = index in buttons[], -1 = niets ingedrukt

int sequence[100]; // Te raden melodie; elk cijfer 0 - 3 als index in notes[] resp. buttons[]

int sequenceLength = 0; // Lengte van de melodie tot dusver

int currentNote = -1; // Nu te raden / af te spelen noot als index in sequence[]

void setup() {

for(int i=0; i<4; i++) {

pinMode(buttons[i], INPUT);

pinMode(leds[i], OUTPUT);

}

pinMode(speaker, OUTPUT);

randomSeed(analogRead(0)); // Toevalsgetalgenerator initialiseren

}

void loop() {

if(guessing) { // De speler is aan de beurt

// Check of een knop is ingedrukt

int currentButton = -1;

for(int i=0; i<4; i++) {

if(digitalRead(buttons[i]) == HIGH) {

currentButton = i;

break;

}

}

if(currentButton != lastButton) { // Is er iets veranderd?

if(lastButton != -1) { // Er was een knop ingedrukt, nu is deze losgelaten

digitalWrite(leds[lastButton], LOW);

noTone(speaker);

delay(10); // Stuiteren bij loslaten vermijden

lastButton = -1;

if(currentNote < sequenceLength - 1) { // De volgende noot is aan de beurt

currentNote++;

}

else { // Helemaal goed ingevoerd => nieuwe melodie afspelen

currentNote = -1;

delay(500);

guessing = false;

}

}

if(currentButton != -1) { // Er is een nieuwe knop ingedrukt

if(currentButton == sequence[currentNote]) { // Hoort de knop bij de volgende toon van de melodie?

digitalWrite(leds[currentButton], HIGH);

tone(speaker, notes[currentButton], 1000);

lastButton = currentButton;

delay(10); // Stuiteren vermijden

}

else { // Verkeerde toets/toon gekozen

tone(speaker, 98); // Note G2

delay(500);

noTone(speaker);

tone(speaker, 65); // Note C2

delay(500);

noTone(speaker);

delay(200);

currentNote = -1;

sequenceLength = 0; // Nieuwe melodie starten

guessing = false;

}

}

}

}

else { // Melodie voorspelen

if(currentNote == -1) { // Melodie-start? Dan achteraan een random note toevoegen

sequence[sequenceLength] = random(0, 4);

sequenceLength++;

currentNote = 0;

}

if(currentNote < sequenceLength) { // Zijn er nog noten te spelen?

digitalWrite(leds[sequence[currentNote]], HIGH);

tone(speaker, notes[sequence[currentNote]]);

delay(500);

digitalWrite(leds[sequence[currentNote]], LOW);

noTone(speaker);

currentNote++;

delay(100);

}

else { // Alle noten gespeeld => Speler moet raden

currentNote = 0;

guessing = true;

}

}

}